25. Februar 2020

Word: Namensschilder für Veranstaltungen schnell und umweltschonend erstellen

Für die Teilnehmer von Veranstaltungen und Seminaren stelle ich Namensschilder her. Da fühlt man sich als Teilnehmer doch gleich ein wenig erwartet. Ganz abgesehen davon ist es für mich sehr hilfreich.

Mit dem hier vorgestellten Tool könnt Ihr auf normalem Druckerpapier doppelseitig bedruckte Schilder herstellen. Die A4-Seite wird zweimal gefaltet, was dem Namensschild gleich etwas Stabilität verschafft. Es muss also kein wertvolles, schweres Papier benutzt werden, für etwas, was nachher in der Regel in den Papierkorb wandert.

In der hier vorgestellten Lösung wird das Hauptdokument die Datenquelle immer finden, wenn sie im gleichen Verzeichnis abgelegt wird und den Namen behält. Dafür sorgt ein kleines Makro, das beim Öffnen des Hauptdokumentes aufgerufen wird.

Die Lösung besteht aus zwei Dateien:

Namensschilder_Hauptdokument.docm (Makro beim Öffnen)
Namensschilder_Datenquelle.xlsx

Das Word-Dokument beinhaltet zwei Makros, die jeweils beim Öffnen und beim Schließen des Dokumentes ausgeführt werden. Beim Öffnen wird das Hauptdokument mit der Excel-Teilnehmerliste in der Datei Namensschilder_Datenquelle.xlsx verbunden und beim Schließen wieder von dieser getrennt. Das hat den Vorteil, dass beide Dateien in ein beliebiges Verzeichnis kopiert werden können und dort klaglos ihre Arbeit erledigen.

Anleitung:

Kopiert das Word-Dokument und die Excel-Arbeitsmappe zusammen in ein Verzeichnis Eurer Wahl.
Öffnet die Excel-Arbeitsmappe und tragt dort die Teilnehmer in die Tabelle ein.
Öffnet das Word-Dokument. Das Dokument sollte sich jetzt automatisch, mit der Teilnehmerliste verbunden haben.
Mit dem Befehl - Sendungen- Fertig stellen und zusammenführen können die Namensschilder jetzt erstellt und gedruckt werden.

Der Code im Word - Dokument:

Private Sub Document_Open()
' Beim Öffnen des Dokuments wird das Dokument mit der Seriendruckqeulle
' Namensschilder_Datenquelle.xlsx im gleichen Verzeichnis verbunden
On Error GoTo er
Const NameQuelldatei As String = "\Namensschilder_Datenquelle.xlsx"

With Me.MailMerge
    .MainDocumentType = wdCatalog
    .OpenDataSource _
      Name:=Me.Path & NameQuelldatei, _
      LinkToSource:=True, _
      ReadOnly:=True, _
      AddToRecentFiles:=False, _
      SQLStatement:="Select * From [Teilnehmerliste$]"
    .ViewMailMergeFieldCodes = False
End With

ex:
On Error Resume Next
Exit Sub
er:
MsgBox Err.Description & vbNewLine & "Document_Open/" & Me.Name
Resume ex
Resume
End Sub

Private Sub Document_Close()
' Beim Schließen des Dokuments wird die Verbindung zur Datenquelle gekappt
On Error GoTo er
Me.MailMerge.MainDocumentType = wdNotAMergeDocument
ex:
On Error Resume Next
Exit Sub
er:
MsgBox Err.Description & vbNewLine & "Document_Close/" & Me.Name
Resume ex
Resume
End Sub